8.х Группировка нескольких наборов данных

Всем привет. Ребят, есть отчет у меня такой. Проблема в том, что в основном наборе я выбираю номенклатуру, чтобы получить срез последних цен в других наборах. Но данные получаются дублируются по номенклатуре (естественно). Если 10 разных номенклатур, то и будет 10 строчек с этими номенклатурами, а надо, чтобы была одна. Вопрос: как?

Объединить ?

Не понял. Что именно объединить?

Ну вот например. Должно быть везде 1. Другие колонки с суммой, сбестоимостью и прочей хренью - суммируются. А нужно сгруппировать.

--- Объединение сообщений, 15 дек 2015 ---

Забыл добавить. Колонок много и группировать в настройках не вариант.

Да тупанул малясь, ляпнул не вникая в тему

Бывает

Точно, понял. Ща попробую.

А почему все через запрос не захотел - быстрее работать будет чем через наборы.

Не получается сделать в одном запросе срез последних. Мне их много нужно будет сделать.

ну почему? Это бразно задача как получить курсы валют на каждый день. или как получить цену последней реализации

Нет. У меня есть дата заказ наряда. На нее нужно посчитать закупочную цену данной номенклатуры, чтобы узнать точную себестоимость.

НУ и чем это отличается от того что
у тебя есть период с 1 по 31 и надо на каждую дату получилть либо сотаток на складе либо курс валюты, даже если не было движений

--- Объединение сообщений, 15 дек 2015 ---

Если интересно
Вот
http://infostart.ru/public/101321/
http://kb.mista.ru/article.php?id=579

Да, уже нашел их. Сижу делаю.

Ну там таблицу с датами можно заменить на запрос из Регламентированого производственного календаря

Кому интересно, то получился вот такой запросик. По которому выбирается последняя дата в регистре цены по нужному типу цен. А потом получается цена, на эту дату. Если строчки в регистре нет, то подставляется цена продажи данной номенклатуры.

Код:

ВЫБРАТЬ РАЗРЕШЕННЫЕ
    ЗаказНарядТовары.Ссылка.Дата КАК Дата,
    ЗаказНарядТовары.Ссылка.Автомобиль КАК Автомобиль,
    ЗаказНарядТовары.Номенклатура КАК Номенклатура_ШиныДиски,
    СУММА(ЗаказНарядТовары.СуммаВсего) КАК СуммаПродажи_ШиныДиски,
    ЗаказНарядТовары.Количество КАК Количество_ШиныДиски,
    ЗаказНарядТовары.Цена КАК ЦенаПродажи
ПОМЕСТИТЬ ВТ_Номенклатура_Шины_Диски
ИЗ
    Документ.ЗаказНаряд.Товары КАК ЗаказНарядТовары
ГДЕ
    ЗаказНарядТовары.Ссылка.Проведен
    И ЗаказНарядТовары.Ссылка.Автомобиль В
            (ВЫБРАТЬ
                ОстаткиАвтомобилейОбороты.Автомобиль
            ИЗ
                РегистрНакопления.ОстаткиАвтомобилей.Обороты(&ДатаНачала, &ДатаОкончания, Регистратор, СкладКомпании.Организация В (&ДоступныеОрганизации)) КАК ОстаткиАвтомобилейОбороты
            ГДЕ
                ОстаткиАвтомобилейОбороты.Регистратор ССЫЛКА Документ.РеализацияАвтомобилей)
    И ЗаказНарядТовары.Номенклатура В ИЕРАРХИИ(&ШиныДиски)

СГРУППИРОВАТЬ ПО
    ЗаказНарядТовары.Ссылка.Автомобиль,
    ЗаказНарядТовары.Номенклатура,
    ЗаказНарядТовары.Количество,
    ЗаказНарядТовары.Цена,
    ЗаказНарядТовары.Ссылка.Дата
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    МАКСИМУМ(Цены.Период) КАК МаксимальнаяДата,
    ВТ_Номенклатура_Шины_Диски.Автомобиль,
    ВТ_Номенклатура_Шины_Диски.Номенклатура_ШиныДиски,
    ВТ_Номенклатура_Шины_Диски.СуммаПродажи_ШиныДиски,
    ВТ_Номенклатура_Шины_Диски.Количество_ШиныДиски,
    ВТ_Номенклатура_Шины_Диски.ЦенаПродажи
ПОМЕСТИТЬ ВТ_МаксимальнаяДата_ШиныДиски
ИЗ
    ВТ_Номенклатура_Шины_Диски КАК ВТ_Номенклатура_Шины_Диски
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.Цены КАК Цены
        ПО ВТ_Номенклатура_Шины_Диски.Номенклатура_ШиныДиски = Цены.Номенклатура
            И (Цены.ТипЦен = ЗНАЧЕНИЕ(Справочник.ТипыЦен.ОсновнойТипЦенЗакупки))
            И ВТ_Номенклатура_Шины_Диски.Дата >= Цены.Период

СГРУППИРОВАТЬ ПО
    ВТ_Номенклатура_Шины_Диски.Автомобиль,
    ВТ_Номенклатура_Шины_Диски.Номенклатура_ШиныДиски,
    ВТ_Номенклатура_Шины_Диски.СуммаПродажи_ШиныДиски,
    ВТ_Номенклатура_Шины_Диски.Количество_ШиныДиски,
    ВТ_Номенклатура_Шины_Диски.ЦенаПродажи
;

////////////////////////////////////////////////////////////////////////////////
УНИЧТОЖИТЬ ВТ_Номенклатура_Шины_Диски
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ВТ_МаксимальнаяДата_ШиныДиски.МаксимальнаяДата,
    ВТ_МаксимальнаяДата_ШиныДиски.Автомобиль,
    ВТ_МаксимальнаяДата_ШиныДиски.Номенклатура_ШиныДиски,
    ВТ_МаксимальнаяДата_ШиныДиски.СуммаПродажи_ШиныДиски,
    ВТ_МаксимальнаяДата_ШиныДиски.Количество_ШиныДиски,
    ЕСТЬNULL(Цены.Цена, ВТ_МаксимальнаяДата_ШиныДиски.ЦенаПродажи) КАК ЦенаЗакупки,
    ВТ_МаксимальнаяДата_ШиныДиски.Количество_ШиныДиски * ЕСТЬNULL(Цены.Цена, ВТ_МаксимальнаяДата_ШиныДиски.ЦенаПродажи) КАК Себестоимость_ШиныДиски
ПОМЕСТИТЬ ВТ_Себестоимость_ШиныДиски
ИЗ
    ВТ_МаксимальнаяДата_ШиныДиски КАК ВТ_МаксимальнаяДата_ШиныДиски
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.Цены КАК Цены
        ПО ВТ_МаксимальнаяДата_ШиныДиски.Номенклатура_ШиныДиски = Цены.Номенклатура
            И ВТ_МаксимальнаяДата_ШиныДиски.МаксимальнаяДата = Цены.Период
            И (Цены.ТипЦен = ЗНАЧЕНИЕ(Справочник.ТипыЦен.ОсновнойТипЦенЗакупки))
;

////////////////////////////////////////////////////////////////////////////////
УНИЧТОЖИТЬ ВТ_МаксимальнаяДата_ШиныДиски
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ВТ_Себестоимость_ШиныДиски.Автомобиль,
    СУММА(ВТ_Себестоимость_ШиныДиски.СуммаПродажи_ШиныДиски) КАК СуммаПродажи_ШиныДиски,
    СУММА(ВТ_Себестоимость_ШиныДиски.Себестоимость_ШиныДиски) КАК Себестоимость_ШиныДиски
ИЗ
    ВТ_Себестоимость_ШиныДиски КАК ВТ_Себестоимость_ШиныДиски

СГРУППИРОВАТЬ ПО
    ВТ_Себестоимость_ШиныДиски.Автомобиль
;

////////////////////////////////////////////////////////////////////////////////
УНИЧТОЖИТЬ ВТ_Себестоимость_ШиныДиски

Ну результат нужный получаешь? Работает быстрее?

Результат вроде нужный, но по скорости особо не заметно.