8.х Обработка заполнение дополнительного реквизита

Тема в разделе "Отчеты и обработки для "1С:Предприятие 8"", создана пользователем duke2003, 14 июн 2019.

0/5, Голосов: 0
  1. TopicStarter Overlay
    duke2003
    Offline

    duke2003

    Регистрация:
    14 июн 2019
    Сообщения:
    15
    Симпатии:
    0
    Баллы:
    1
    здравствуйте! Есть справочник - "Номенклатура". В виде номенклатуры добавлен дополнительный реквизит - "ГОСТ". Нужно из поля - "Описание" перенести данные в доп. реквизит.

    делаю так:
    Код:
    Запрос = Новый Запрос;
    Запрос.Текст =
        "ВЫБРАТЬ
        |   Номенклатура.Код КАК Код,
        |   Номенклатура.Наименование КАК Наименование,
        |   Номенклатура.Описание КАК Описание
        |ИЗ
        |   Справочник.Номенклатура КАК Номенклатура
        |ГДЕ
        |   Номенклатура.Описание <> &Описание";
    Запрос.УстановитьПараметр("Описание", "");
    РезультатЗапроса = Запрос.Выполнить();
    ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();
    Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
     
     МояНоменклатура = Справочники.Номенклатура.НайтиПоНаименованию(ВыборкаДетальныеЗаписи.Наименование).ПолучитьОбъект();
        МояНоменклатура.Описание = "";
     
        МояНовыйРеквизит = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.НайтиПоНаименованию("ГОСТ");
        МояНовыйРеквизит.Значение = ВыборкаДетальныеЗаписи.Описание;
     
        МояНоменклатура.Записать();
        Сообщить(МояНоменклатура.Наименование + " " + ВыборкаДетальныеЗаписи.Описание)
    КонецЦикла;
    ругается вот так:
    Значение не является значением объектного типа (Значение)
    МояНовыйРеквизит.Значение = ВыборкаДетальныеЗаписи.Описание;

    подскажите, как обратиться к доп. реквизиту и записать в него данные?
    duke2003, 14 июн 2019
    #1
  2. TopicStarter Overlay
    duke2003
    Offline

    duke2003

    Регистрация:
    14 июн 2019
    Сообщения:
    15
    Симпатии:
    0
    Баллы:
    1
    не кто не знает что ли?
    duke2003, 15 июн 2019
    #2
  3. 1cUserAndrew
    Offline

    1cUserAndrew Профессионал в 1С Команда форума

    Регистрация:
    27 май 2010
    Сообщения:
    5.151
    Симпатии:
    217
    Баллы:
    104
    Значения дополнительных реквизитов хранятся в табличной части справочника.
    Т.е. для того, чтобы установить значение доп.реквизита элементу номенклатуры, Вам надо в табличную часть "ДополнительныеРеквизиты" добавить строку (или изменить значение в имеющейся строке, если она уже есть).

    upload_2019-6-16_12-36-12.png

    Лучше всего, воспользоваться процедурами общих модулей.
    Для установки значения доп. реквизита я не нашел в свое время процедуры, которая бы просто установила переданное значение доп.реквизита. Нашел только такую, которая принимает на вход специально подготовленную таблицу. Ее и использовал, предварительно написав свою:

    Код:
    Процедура УстановитьЗначениеДопСвойства(ВладелецСвойства, Свойство, ЗначениеСвойства) Экспорт

    Если ТипЗнч(Свойство) = Тип("ПланВидовХарактеристикСсылка.ДополнительныеРеквизитыИСведения") Тогда
        ДопСвойство = Свойство;
    Иначе
        ДопСвойство = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.НайтиПоРеквизиту("Имя", Свойство);
    КонецЕсли;
  
    Если НЕ ЗначениеЗаполнено(ДопСвойство) Тогда
        Возврат;
    КонецЕсли;
  
    ТаблицаСвойствИЗначений = Новый ТаблицаЗначений;
    ТаблицаСвойствИЗначений.Колонки.Добавить("Свойство", Новый ОписаниеТипов("ПланВидовХарактеристикСсылка.ДополнительныеРеквизитыИСведения"));
    ТаблицаСвойствИЗначений.Колонки.Добавить("Значение");
  
    СтрокаСвойств = ТаблицаСвойствИЗначений.Добавить();
    СтрокаСвойств.Свойство = ДопСвойство;
    СтрокаСвойств.Значение = ЗначениеСвойства;
  
    УправлениеСвойствами.ЗаписатьСвойстваУОбъекта(ВладелецСвойства, ТаблицаСвойствИЗначений);

КонецПроцедуры
    Вызываете эту процедуру, передав соответствующие параметры:
    ВладелецСвойства - ваша номенклатура;
    Свойство - доп.реквизит, который хотите установить (передать можно либо ссылку на элемент плана видов характеристик, либо имя для разработчика, которое указано в пользовательском режиме для данного доп.реквизита);
    ЗначениеСвойства - значение доп.реквизита.

    Т.е. в Вашем случае вместо строки
    Код:
    МояНовыйРеквизит.Значение = ВыборкаДетальныеЗаписи.Описание;
    напишите
    Код:
    УстановитьЗначениеДопСвойства(МояНоменклатура, МояНовыйРеквизит, ВыборкаДетальныеЗаписи.Описание)
    Последнее редактирование: 16 июн 2019
    1cUserAndrew, 16 июн 2019
    #3
    duke2003 нравится это.
  4. TopicStarter Overlay
    duke2003
    Offline

    duke2003

    Регистрация:
    14 июн 2019
    Сообщения:
    15
    Симпатии:
    0
    Баллы:
    1
    ругается в Общем модуле УправлениеСвойствами.
    Код:
    {ОбщийМодуль.УправлениеСвойствами.Модуль(1168)}: Метод объекта не обнаружен (ПолучитьОбъект)
            ВладелецСвойствОбъект = ВладелецСвойств.ПолучитьОбъект();
    625 .jpg
    duke2003, 16 июн 2019
    #4
  5. 1cUserAndrew
    Offline

    1cUserAndrew Профессионал в 1С Команда форума

    Регистрация:
    27 май 2010
    Сообщения:
    5.151
    Симпатии:
    217
    Баллы:
    104
    Точно ссылку на номенклатуру передаете?
    1cUserAndrew, 16 июн 2019
    #5
  6. TopicStarter Overlay
    duke2003
    Offline

    duke2003

    Регистрация:
    14 июн 2019
    Сообщения:
    15
    Симпатии:
    0
    Баллы:
    1
    вот так:
    МояНоменклатура = Справочники.Номенклатура.НайтиПоНаименованию(ВыборкаДетальныеЗаписи.Наименование).ПолучитьОбъект();
    МояНовыйРеквизит = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.НайтиПоНаименованию("ГОСТ");
    УстановитьЗначениеДопСвойства(МояНоменклатура, МояНовыйРеквизит, ВыборкаДетальныеЗаписи.Описание);
    duke2003, 16 июн 2019
    #6
  7. 1cUserAndrew
    Offline

    1cUserAndrew Профессионал в 1С Команда форума

    Регистрация:
    27 май 2010
    Сообщения:
    5.151
    Симпатии:
    217
    Баллы:
    104
    Ну да, я не заметил сразу, что Вы передаете не ссылку, а объект.
    Уберите получение объекта номенклатуры.
    Код:
    МояНоменклатура = Справочники.Номенклатура.НайтиПоНаименованию(ВыборкаДетальныеЗаписи.Наименование);
    --- Объединение сообщений, 16 июн 2019 ---
    Вообще, поиск номенклатуры по наименованию - это лишнее.
    Вместо наименования в Вашем запросе можно саму ссылку выбирать.
    1cUserAndrew, 16 июн 2019
    #7
    duke2003 нравится это.
  8. TopicStarter Overlay
    duke2003
    Offline

    duke2003

    Регистрация:
    14 июн 2019
    Сообщения:
    15
    Симпатии:
    0
    Баллы:
    1
    теперь ругается на МояНоменклатура.Записать();
    Код:
    {Обработка.ЗаполнениеГОСТизОписания.Форма.Форма.Форма(53)}: Метод объекта не обнаружен (Записать)
        МояНоменклатура.Записать();
    а если закоментить, то процедура выполняется, но ни чего не сохраняется
    duke2003, 16 июн 2019
    #8
  9. 1cUserAndrew
    Offline

    1cUserAndrew Профессионал в 1С Команда форума

    Регистрация:
    27 май 2010
    Сообщения:
    5.151
    Симпатии:
    217
    Баллы:
    104
    Верно, записывать не надо. Запись выполнится в той процедуре.
    Почему не сохраняется, сложно сказать.
    Проверьте настройки вашего доп.реквизита (в пользовательском режиме). В частности его тип значения. Я так понимаю, тип должен быть строковый, раз вы туда описание записываете.
    1cUserAndrew, 16 июн 2019
    #9
  10. TopicStarter Overlay
    duke2003
    Offline

    duke2003

    Регистрация:
    14 июн 2019
    Сообщения:
    15
    Симпатии:
    0
    Баллы:
    1
    проверил - доп реквизит - строка
    000(14-28).JPG 001(14-29).JPG

    нашел вот такую процедуру в общих модулях, которая записывает доп реквизиты - УправлениеСвойствами.ЗаписатьСвойстваУОбъекта

    сделал так:
    Код:
    Процедура ЗаполнитьНаСервере()
    // Вставить содержимое обработчика.
    //{{КОНСТРУКТОР_ЗАПРОСА_С_ОБРАБОТКОЙ_РЕЗУЛЬТАТА
    // Данный фрагмент построен конструктором.
    // При повторном использовании конструктора, внесенные вручную изменения будут утеряны!!!
  
    Запрос = Новый Запрос;
    Запрос.Текст =
        "ВЫБРАТЬ
        |   Номенклатура.Код КАК Код,
        |   Номенклатура.Наименование КАК Наименование,
        |   Номенклатура.Описание КАК Описание
        |ИЗ
        |   Справочник.Номенклатура КАК Номенклатура
        |ГДЕ
        |   Номенклатура.Описание <> &Описание";
  
    Запрос.УстановитьПараметр("Описание", "");
  
    РезультатЗапроса = Запрос.Выполнить();
  
    ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();
  
    Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
        // Вставить обработку выборки ВыборкаДетальныеЗаписи
        МояНоменклатура = Справочники.Номенклатура.НайтиПоНаименованию(ВыборкаДетальныеЗаписи.Наименование);
        ДопРеквизитГОСТ = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.НайтиПоРеквизиту("Заголовок", "ГОСТ");
      
        ТаблицаДопРеквизитов = Новый ТаблицаЗначений;
        ТаблицаДопРеквизитов.Колонки.Добавить("Свойство", Новый ОписаниеТипов("ПланВидовХарактеристикСсылка.ДополнительныеРеквизитыИСведения"));
        ТаблицаДопРеквизитов.Колонки.Добавить("Значение", Новый ОписаниеТипов("Строка"));
      
        НовыйРекизит = ТаблицаДопРеквизитов.Добавить();
        НовыйРекизит.Свойство = ДопРеквизитГОСТ;
        НовыйРекизит.Значение = ВыборкаДетальныеЗаписи.Описание;
      
        УправлениеСвойствами.ЗаписатьСвойстваУОбъекта(МояНоменклатура, ТаблицаДопРеквизитов);

        Сообщить(МояНоменклатура.Наименование + " " + ВыборкаДетальныеЗаписи.Описание)
    КонецЦикла;
  
    //}}КОНСТРУКТОР_ЗАПРОСА_С_ОБРАБОТКОЙ_РЕЗУЛЬТАТА
КонецПроцедуры


    ошибок тоже нет, и тоже ни чего не сохраняется.
    duke2003, 18 июн 2019
    #10
  11. 1cUserAndrew
    Offline

    1cUserAndrew Профессионал в 1С Команда форума

    Регистрация:
    27 май 2010
    Сообщения:
    5.151
    Симпатии:
    217
    Баллы:
    104
    Ну, по сути да, это тот же код, что и в моей процедуре.
    Еще есть мысль, почему не работает, - возможно, не находится доп.реквизит (хотя по наименованию должен был найтись).

    Вообще, есть же специальный реквизит, по которому в конфигураторе предполагается обращаться к этому доп.реквизиту.

    upload_2019-6-18_11-18-13.png

    Посмотрите, какое имя для разработчика задано для этого доп.реквизита.
    Это имя строкой и передавайте в мою процедуру в параметр "Свойство".
    И в запросе выбирайте ссылку вместо поиска по наименованию.

    Код:
    Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ
|   Номенклатура.Ссылка КАК Ссылка,
|   Номенклатура.Описание КАК Описание
|ИЗ
|   Справочник.Номенклатура КАК Номенклатура
|ГДЕ
|   Номенклатура.Описание <> &Описание";

Запрос.УстановитьПараметр("Описание", "");

РезультатЗапроса = Запрос.Выполнить();
ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();

Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
    УстановитьЗначениеДопСвойства(ВыборкаДетальныеЗаписи.Ссылка, "ТутНапишитеИмяДляРазработчика", ВыборкаДетальныеЗаписи.Описание);
КонецЦикла;
    1cUserAndrew, 18 июн 2019
    #11
    duke2003 нравится это.
  12. TopicStarter Overlay
    duke2003
    Offline

    duke2003

    Регистрация:
    14 июн 2019
    Сообщения:
    15
    Симпатии:
    0
    Баллы:
    1
    1cUserAndrew,спасибо за помощь
    все получилось
    --- Объединение сообщений, 19 июн 2019 ---
    1cUserAndrew, а программно имя для разработчика можно вытаскивать?
    Последнее редактирование: 19 июн 2019
    duke2003, 19 июн 2019
    #12
  13. 1cUserAndrew
    Offline

    1cUserAndrew Профессионал в 1С Команда форума

    Регистрация:
    27 май 2010
    Сообщения:
    5.151
    Симпатии:
    217
    Баллы:
    104
    Да, у плана вида характеристик "ДополнительныеРеквизитыИСведения" есть реквизит "Имя". Вот это оно и есть.
    1cUserAndrew, 19 июн 2019
    #13
    duke2003 нравится это.
  14. TopicStarter Overlay
    duke2003
    Offline

    duke2003

    Регистрация:
    14 июн 2019
    Сообщения:
    15
    Симпатии:
    0
    Баллы:
    1
    реквизит с именем "ГОСТ" один, имя разработчика у него - ГОСТ_ccbd71b2f88c42cfb5333bea2d7f9c26

    а когда я пытаюсь его вытащить так:
    ДопРеквизитГОСТ = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.НайтиПоНаименованию("ГОСТ");
    или так
    ДопРеквизитГОСТ = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.НайтиПоРеквизиту("Заголовок", "ГОСТ");

    имя вытаскивается вот такое:
    ДопРеквизитГОСТ.Имя - ГОСТ_17c47abfbf144039a22ede9eb7931d79.

    поэтому видимо раньше и не сохранялось, пока явно не прописали имя разработчика, потому что вытаскивается совсем другое имя
    Последнее редактирование: 20 июн 2019
    duke2003, 19 июн 2019
    #14
  15. TopicStarter Overlay
    duke2003
    Offline

    duke2003

    Регистрация:
    14 июн 2019
    Сообщения:
    15
    Симпатии:
    0
    Баллы:
    1
    1cUserAndrew, спасибо
    задача решена
    duke2003, 21 июн 2019
    #15
Похожие темы
  1. Sepegka

    8.х Заполнение реквизита

    Sepegka, 1 окт 2008, в разделе: Конфигурирование на платформе "1С:Предприятие 8"
    Ответов:
    1
    Просмотров:
    1.142
    opkc
    1 окт 2008
  2. djilda

    8.х УТ Ограничение длины строки дополнительного реквизита

    djilda, 8 дек 2011, в разделе: "1С:Управление торговлей УТ"
    Ответов:
    3
    Просмотров:
    5.123
    x_under
    15 дек 2011
  3. John95103

    8.х Автоматическое заполнение реквизита табличной части из реквизита справочника

    John95103, 29 апр 2013, в разделе: Общие вопросы "1С:Предприятие 8"
    Ответов:
    3
    Просмотров:
    2.859
    1cUserAndrew
    30 апр 2013
  4. Nik02071

    [РЕШЕНО] Програмное заполнение дополнительного реквизита 1с8.3 бп3

    Nik02071, 13 май 2014, в разделе: Конфигурирование на платформе "1С:Предприятие 8"
    Ответов:
    9
    Просмотров:
    22.809
    Nik02071
    14 май 2014
  5. rosveta

    8.х Имя дополнительного реквизита

    rosveta, 19 ноя 2015, в разделе: Конфигурирование на платформе "1С:Предприятие 8"
    Ответов:
    10
    Просмотров:
    1.746
    rosveta
    20 ноя 2015
Загрузка...