8.х Проблема с запросом к табличной части справочника

Существует справочник ДоговорыАбонентов. В нем есть Табличная Часть "ГородскиеНомера". Пытаюсь выдернуть данные по номерам из табличной части справочника с помощью запроса:

Запрос = Новый Запрос;
Запрос.УстановитьПараметр("Организация",Организация);
Запрос.Текст= "ВЫБРАТЬ
| ДоговорыАбонентов.Абонент,
| ДоговорыАбонентов.ГородскиеНомера.(
| ГорНомер,
| Цена,
| ДатаВКЛ,
| ДатаОТКЛ
| )
|ИЗ
| Справочник.ДоговорыАбонентов КАК ДоговорыАбонентов
|ГДЕ
| ДоговорыАбонентов.Абонент = &Организация" ;
Рез=Запрос.Выполнить().Выгрузить();

Но вижу только данные поля "Абонент". Помогите вытащить данные по ГородкимНомерам.

Отдельно присоединяй табличную часть.
По ссылке, внутренним соединением.

Я к сожалению новичок в 1С. Если можно, пример напиши, плиз.

изменил немного запрос:

Запрос = Новый Запрос;
Запрос.УстановитьПараметр("Организация",Организация);
Запрос.Текст= "ВЫБРАТЬ
| ДоговорыАбонентов.Абонент,
| ДоговорыАбонентов.ГородскиеНомера.(
| ГорНомер как ГН,
| Цена как ЦенаГН,
| ДатаВКЛ как ВклГН,
| ДатаОТКЛ как ОтклГН
| )
|ИЗ
| Справочник.ДоговорыАбонентов КАК ДоговорыАбонентов
|ГДЕ
| ДоговорыАбонентов.Абонент = &Организация" ;
Рез=Запрос.Выполнить().Выгрузить();
ТС=Рез.ВыбратьСтроку();

В ТаблицеЗначений вижу даные. Но как от туда вытянуть строки для обработки в цикле????

для каждого строка из Тс цикл
....
конецЦикла;

к сожалению не срабатывает. В результате запроса (Рез) есть ещё ТаблицаЗначений (ГородскиеНомера) с вышеуказанными полями. Не получается туда добраться и передать значения полей строк в цикл....

|ИЗ
| Справочник.ДоговорыАбонентов КАК ДоговорыАбонентов
| ВНУТРЕННЕЕ СОЕДИНЕНИЕ
| Справочник.ДоговорыАбонентов.ГородскиеНомера КАК ДоговорыАбонентовГородскиеНомера
| ПО ДоговорыАбонентов.Ссылка = ДоговорыАбонентовГородскиеНомера.Ссылка

извини за мою тупость, можно увидеть полный текст запроса?

Код:

Запрос = Новый Запрос;
Запрос.УстановитьПараметр("Организация",Организация);
Запрос.Текст= "ВЫБРАТЬ
| ДоговорыАбонентов.Абонент,
| ДоговорыАбонентовГородскиеНомера.ГорНомер как ГН,
| ДоговорыАбонентовГородскиеНомера.Цена как ЦенаГН,
| ДоговорыАбонентовГородскиеНомера.ДатаВКЛ как ВклГН,
| ДоговорыАбонентовГородскиеНомера.ДатаОТКЛ как ОтклГН
|
|ИЗ
| Справочник.ДоговорыАбонентов КАК ДоговорыАбонентов
| ВНУТРЕННЕЕ СОЕДИНЕНИЕ 
| Справочник.ДоговорыАбонентов.ГородскиеНомера КАК ДоговорыАбонентовГородскиеНомера
| ПО ДоговорыАбонентов.Ссылка = ДоговорыАбонентовГородскиеНомера.Ссылка
|ГДЕ
| ДоговорыАбонентов.Абонент = &Организация"

Выборка = Запрос.Выполнить().Выбрать();
Пока Выборка.Следующий() Цикл
...тут происходит перебор строк
...В атрибутах переменной Выборка содержатся данные
...Выборка.ГН - это ДоговорыАбонентовГородскиеНомера.ГорНомер и т.п.
КонецЦикла;

LordKim
Спасибо большое. Все как по маслицу пошло)))